#!/bin/sh
# dependencias-modulos: las reglas de dependencia por modulos de Fortran, para
# que un cambio en un modulo recompile a TODOS los que le hacen 'use'.
#
#   dependencias-modulos DIR SUFIJO [PREFIJO]
#
# Barre los .f90 de DIR y escribe por la salida estandar, para cada fuente que
# usa un modulo definido en ese mismo directorio, una regla
#
#   PREFIJO<fuente>SUFIJO: PREFIJO<definidor>SUFIJO
#
# (SUFIJO es .o o .lo segun el directorio compile a mano o con libtool). Lo
# llama el Makefile de cada directorio en el build y el resultado se incluye
# con '-include': NO se versiona, porque es derivado de los fuentes y un
# archivo asi mantenido a mano queda viejo --paso de verdad: xf90 usa
# common_sc1mod, la regla no estaba, make dio 0 sin recompilarlo y el binario
# quedo despareja, con violacion de segmento en cualquier deck (09/11/2026)--.
#
# Que mira: 'module NOMBRE' define (no 'module procedure'); 'use NOMBRE' y
# 'use, intrinsic :: NOMBRE' usan (los intrinsecos se ignoran). Mayusculas y
# minusculas dan igual, como en Fortran.
#
# Copyright (C) Diego Saravia <dsa@unsa.edu.ar>
# GPL version 3 o posterior.
set -eu
DIR=${1:?falta el directorio de los fuentes}
SUF=${2:?falta el sufijo de los objetos (.o o .lo)}
PRE=${3:-}
LC_ALL=C exec awk -v suf="$SUF" -v pre="$PRE" '
BEGIN {
   for (k = 1; k < ARGC; k++) {
      archivo = ARGV[k]
      base = archivo
      sub(/^.*\//, "", base); sub(/\.[fF]90$/, "", base)
      while ((getline linea < archivo) > 0) {
         l = tolower(linea)
         sub(/\r$/, "", l)        # un fuente con CRLF (stringmod.f90) no corta la dependencia
         sub(/^[ \t]+/, "", l)
         if (l ~ /^module[ \t]+[a-z]/ && l !~ /^module[ \t]+procedure/) {
            nombre = l; sub(/^module[ \t]+/, "", nombre); sub(/[ \t!].*$/, "", nombre)
            define[nombre] = base
         } else if (l ~ /^use[ \t,]/) {
            if (l ~ /^use[ \t]*,[ \t]*intrinsic/) continue
            nombre = l
            sub(/^use[ \t]*(,[ \t]*non_intrinsic[ \t]*)?(::)?[ \t]*/, "", nombre)
            sub(/[ \t,!].*$/, "", nombre)
            if (nombre != "") usa[base, nombre] = 1
         }
      }
      close(archivo)
   }
   for (par in usa) {
      split(par, p, SUBSEP)
      if (p[2] in define && define[p[2]] != p[1])
         print pre p[1] suf ": " pre define[p[2]] suf
   }
}' "$DIR"/*.f90 "$DIR"/*.F90 2>/dev/null
